안녕하세요. 법사 게시판에 매크로 공지글이 이미 있는 것 같지만.. 개별적으로 만든 매크로 및 유용한 매크로 공유를 해보려고 합니다. 문구를 축소하는게 가능한 매크로가 몇 개 있지만 그대로 씁니다. 예를 들면 equipslot, equip, castsequence 같은 명령문은 장비장착, 장비, 연속시전으로 한글 명령문을 쓰면 글자수가 더 축소가 더 된다거나 사용 등의 명령문은 use가 더 적다던가 등의 장점이 있으니 보시고 수정하셔도 되고 수정할 필요가 없는 여유되는 매크로는 그대로 쓰셔도 될 것 같습니다. 하기에 적은 매크로는 서로 조합해 작동이 되도록 추가/수정하실 수 있고 정상 작동되지 않는다면 알려주세요. 전사, 사제, 팁 게시판에도 매크로 글을 가끔 몇 번 올렸지만 법사 게시판에도 만들어 쓰는거랑 알고 있는 내용 등을 같이 공유해봅니다.

#showtooltip
/castsequence [nomod] reset=5 신비한 지능, 냉기 갑옷, 마법 감쇠
/cast [mod:shift]냉기 갑옷;[mod:ctrl]마법 감쇠;[mod:alt]마법 증폭

설명 : 연속시전 리셋 5초로 신지, 냉갑, 마감 / 쉬프트키로 냉갑 / 컨트롤키로 마감 / 알트키로 마증

기본 버프 매크로입니다.

#showtooltip 눈보라
/castsequence reset=10 얼음 회오리, 얼음 보호막, 눈보라, 점멸, 냉기 돌풍

설명 : 리셋 10초로 얼회, 얼보, 눈보라, 점멸, 냉기 돌풍을 씁니다.

광칠 때 귀차니즘을 해결해주지만 상황에 맞게 쓸 수 없는 단점이 존재합니다.
보통 광칠 때 얼보키고 광치실텐데 얼회 다음에 죽지 않기 위해 얼보를 두른단 점에서 첫번째
그리고 얼보를 두르고 들어갔다면 2번째 얼보에서 castsequence 연속시전이 막혀서 먹통될 겁니다.
얼보를 미처 못써서 넘어갔다면 눈보라를 쓰겠죠. 눈보라 다 치는 걸 보고서 몹이 붙어 오는데 점멸을 씁니다.
그런데 몹이 생각보다 빨리 붙거나 점멸을 쓰고자 하는데 stopcasting 문구가 없는게 좀 마음에 걸리네요.
귀차니즘에게 추천

#showtooltip 변이
/stopcasting
/cast [combat] 냉정
/cast [@mouseover,harm][]변이
/emote %t 양변!

설명 : 시전 중이던 주문을 중지 / 전투중일 때 냉정(비전 특성) 발동/ 1순위 마우스오버, 2순위 대상 변이 시전 / 감정표현으로 '대상' 양변! 채팅창 출력

아무래도 combat 조건으로 냉정을 발동시키는 이유는 비전투 중일 때 양풀때문 입니다.
전투 중일 때 양변을 하는 이유는 재양변 목적이 주가 되는 이유이고 그에 따라 빠르게 재양변을 넣기 위함입니다.

이 매크로 공유드리면서 다시금 알게 되었는데 cast는 use로도 동작을 하네요. 하지만 use보단 cast가 여러 조건 한계에서 우월하므로 아이템 장비가 아닌 주문 시전 기술에는 cast가 적합합니다. 
이 점 참고하시어 255 매크로 제한 글자 수에 걸리는 매크로가 있다면 수정을 해볼 수 있겠네요.
원래 use=사용 매크로는 장비나 소모품 등의 아이템에 대한 사용을 할 때 씁니다만 주문에도 범용적으로 쓸 수 있나 봅니다.

#showtooltip
/stopcasting
/cast 냉정
/cast 신비한 마법 강화
/use 13/14 장신구(장신구 이름을 shift 클릭으로 복사해두세요)
/cast 불덩이 작렬

설명 : 시전 중이던 주문을 중지 / 냉정 발동(이 문구엔 위처럼 combat을 넣지 않습니다) / 신마강 발동 / 13과 14번 장신구 자리에 있는 특정한 장신구 발동 / 불작 시전

이 매크로는 주문을 끊고 냉정, 신마강을 발동해서 쓸 사효 장신구가 13번 또는 14번 어디에 있더라도 사용되도록 돕고 불작을 쓰는 매크로입니다. 냉정, 신마강 주문이란 게 글쿨이 없다면 정상 작동할 것입니다.

#showtooltip
/cast !눈보라

설명 : 눈보라 채널링 스킬이 끊어지지 않도록 !를 붙였습니다.

채널링 스킬은 느낌표를 쓰거나 조건문에 nochanneling 조건 문구를 적용시켜서 쓰면 됩니다.
이 매크로는 눈보라 채널링 틱이 다 되기 전에 눈보라를 써서 틱 손해를 막기 위함이지만 불필요하다고 생각될 수도 있습니다. 그러나 틱 손해때문에 쓴다면 간단하지만 필요한 분들도 있겠죠?

#showtooltip 마나 루비
/사용 마나 루비
/사용 마나 황수정
/사용 마나 비취
/사용 마나 마노

설명 : 만들어 둔 마나 수정을 먹습니다.

#showtooltip 마법 차단
/시전중지
/시전 [@mouseover,harm][] 마법 차단

설명 : 시전 중이던 주문을 끊고 1순위 마우스오버 적대적 / 2순위 대상에게 마법 차단을 시전합니다.
원래 시전 중지가 2번 들어가 있었으나 무의미합니다.

#showtooltip
/tar player
/castsequence [btn:2,mod:shift] reset=10 신비한 지능,냉기 갑옷,마나 보호막
/castsequence [btn:2,mod:ctrl] reset=4 마나 보호막
/castsequence [btn:2] reset=5 음료 창조, 음식 창조
/stopmacro [mod]
/use [btn:1]창조된 흑빵
/use [btn:1]창조된 정제수

설명 : 이 매크로는 제작자가 저입니다. 이런 매크로도 구현하다고 보여드리는 것일 뿐 진짜 실사용 가능한 물빵 매크로는 댓글에 달아 두겠습니다. 그쪽을 확인하십시오.

상기 위 매크로는 글자수는 230/255이고 제한 글자 수내에서 글자 추가가 가능합니다.(255 제한 넘기는 애드온도 있다곤 하던데 애드온 없으면 못 쓰는 매크로는 만들고 싶지 않아서 모르겠네요.)그리고 btn:1은 마우스를 쓰지 않는다면 그냥 액션바에 보이는 동작을 수행합니다.

매크로에 자세하게 설명해드리겠습니다.
매크로 조금만 문구 조정하면 불필요한 문구는 삭제하거나 줄이시고 빵이나 물을 따로 먹는 거도 가능할 겁니다.

1. 대상을 자신으로 잡습니다. (대상 아군에게 버프를 주는 등의 꼬임 방지)

2. 연속시전 우클릭, 쉬프트키를 조합해 리셋 10초로 신지, 냉갑, 마보를 씁니다. (원래는 신지, 냉갑, 얼보, 마감, 물 창조, 빵 창조였습니다. 불편해서 물빵 창조는 빼뒀고 얼보마감은 제 법사 레벨이 현재 23이라 렙이 안되거나 같이 켜두고 쓸 건덕지가 없으므로 따로 빼뒀습니다.)

3. 연속시전 우클릭, 컨트롤키를 조합해 리셋 5초로 마보를 씁니다.(이건 연속시전을 해놨는데 스킬을 하나만 쓰고 있네요. 얼보를 배우면 얼보, 마보 순으로 입력하시고 쓰면 됩니다.)

4. 연속시전 우클릭으로 리셋 5초로 음료 창조, 음식 창조를 합니다. (물빵 만들 때 우클릭으로 순서대로 만들어주시면 되요. 혹시 물이나 빵만 따로 만들고 싶을 때는? 공유해드린 매크로 문구를 응용해서 본인이 더 추가해서 만드시면 됩니다.)

5. 매크로중지 조건문 mod (이거는 의미가 있나 모르겠지만 넣어 뒀습니다. 슬러쉬 명령문 매크로 내에서 ;으로 등가 조건문을 여러개 달 때는 mod매크로를 쓰면 mod키 미적용 문구엔 nomod 조건을 따로 넣어서 쓰는데 이 매크로는 명령문을 나눠서 써서 mod키를 써도 음료 창조, 음식 창조엔 nomod 안써도 정상작동하는 것 같더군요. 글자 수 아까워서도 줄여 쓰는게 좋구요. 아무튼 스탑매크로 명령문 넣은 이건 없어도 될 수도 있습니다.)

6. 사용 좌클릭 빵 창조 (빵을 물보다 먼저 둔 이유는 물보다 빵이 더 적게 만들어지고 액션바 상에서 기본 디폴트 표시가 빵으로 보여서 빵의 수량을 확인할 수 있기 때문이죠. 그리고 #showtooltip 뒤에도 여러가지로 액션바 아이콘을 적시할 수 있지만 앞서 말했다시피 저는 매크로의 글자수를 최대한 줄이려 애씁니다)

7. 사용 좌클릭 물 창조

#showtooltip 
/castsequence [@player] reset=4 얼음 보호막, 마나 보호막

설명 : 연속시전 자신에게 리셋 4초로 얼보, 마보 사용

이전 매크로는 원 버튼으로 다 가능하도록 만들었지만 다 담느라 편의성을 조금 해칩니다. 때문에 재빠르게 쓰기 위한 부분만 필요하다면 이거로 보막 두르시면 됩니다.

#showtooltip
/cast [nomod]냉기계 수호;[mod:shift] 화염계 수호

설명 : 냉기계 수호, 쉬프트키 누르면 화염계 수호

많이들 쓰시는..

#showtooltip 신비한 화살
/시전 [nochanneling:신비한 화살] 신비한 화살

설명 : 신비한 화살이 채널링 스킬이라 이렇게 쓰시면 틱을 조금이라도 아낄 수 있습니다. 스킬 앞에 아마도 눈보라처럼 ! 느낌표를 달아두셔도 될 겁니다.

(하지만 클라이언트 렉때문에 미미하지만 이 매크로도 틱손실에서 완벽하지 않으며 일부 틱 손실은 된다는 견해를 제시하는 분들이 있습니다. 원래는 이 매크로로 틱 손실이 나지 않아야 되는 게 맞지만 로그 분석해서 틱손실 확인을 하고 원인을 클라로 추정하더군요.)

#showtooltip 얼음 방패
/stopcasting
/cast 얼음 방패
/cancelaura [mod:shift] 얼음 방패

설명 : 시전을 끊고 / 얼방을 쓰고 / 쉬프트키를 누르면 얼방을 강제 취소 선택 가능

얼방 계속 안쓰고 풀고 싶을 때가 있죠. 

#showtooltip 얼음 화살
/cast 신비한 마법 강화
/use 13
/use 14
/시전 [nomod,@targettarget,harm][nomod]얼음 화살;[mod:shift,@targettarget,harm][mod:shift]얼음 화살(1 레벨)

설명 : 신마강 발동 / 장신구 13 / 장신구 14를 사용 / 1순위 대상의 대상이 적대적, 2순위 대상에게 얼화 최고렙 / 동일 순위로 쉬프트키로 얼화 1레벨 시전

글쎄요 이 매크로... 신마강을 쓰는 얼화인 걸 보면 와클에서 쓸 매크로는 아닌 것 같습니다. 하지만 신마강없더라도 장신구키면서 작동은 될 겁니다. 신마강 그리고 장신구 13, 14를 같이 터뜨리는 용도인데.. 사효 장신구들 쿨이 겹치는 것들이 많아서 저렇게 해놔도 13, 14 사효 장신구 2개 동시에 못 쓰리라 봅니다. 추가로 신마강과 냉정도 같이 묶으면 좋을테고 스킬은 얼화보단 불작이 더 좋아 보이네요. 응용해서 수정하시길 바랍니다. 그리고 사효 장신구를 자기 원할 때 쓰고 싶다면 방해가 되니 윗 문구 날리시면 됩니다. 또한 1레벨 얼화를 쉬프트로 같은 순위대로 쓸 수 있도록 했습니다.

#showtooltip
/dismount
/stopcasting
/castsequence reset=21 얼음 회오리, 매서운 한파

설명 : 말에서 내립니다 / 시전을 끊습니다 / 연속시전 리셋 21초로 얼회, 한파 시전

말타고 가시다가 적을 만나면 말에서 내려야 되는데 와클은 자동 탈것 내리기가 안되서 얼회를 쓰려는데 그냥 캐릭이 멀뚱멀뚱 봅니다. 때문에 자동으로 탈것에서 내리는 애드온의 도움 또는 강제로 매크로에서 지정해서 내리기 해주셔야 됩니다. 말타는 경우가 아니라 시전 중에도 얼회를 써야될 때도 있죠. 그래서 스탑캐스팅도 넣었습니다. 그리고 연속시전으로 얼회를 쓰고 얼회 기본쿨 25초에 냉기 얼회 특성 2포로 4초 감소 즉 21초 리셋주기로 얼회를 쓰고나면 매서운 한파가 보이는 겁니다. 얼회를 썼는데 적이 계속 달라 붙어서 빠르게 한파 돌리고 얼회를 쳐야 될 때가 있어서요. 리셋 주기를 21초로 해놨는데 솔직히 10초 밑이면 한파가 좀 아까우니 리셋 주기는 개인이 수정해서 쓰세요.

#showtooltip
/cast [@mouseover, help, nodead][help, nodead][@player]하급 저주 해제

설명 : 1순위 마우스오버, 우호적, 살아있는 상태 / 2순위 대상 우호적, 살아있는 상태 / 3순위 본인에게 하급 저주 해제

전천후적인 매크로죠. 비슷한 매크로로 힐러 분들 힐 매크로가 있는데 이 매크로는 대상의 대상 조건문이 없습니다. 그 이유는 힐러 분들처럼 대상의 대상에게 힐을 주지도 않아 불필요할 뿐더러 넣는다면 조건문이 꼬여서 매크로가 아예 동작하지 않을 겁니다. 이대로 쓰시는 걸 권장합니다.

#showtooltip
/stopcasting
/cast 점멸

설명 : 시전끊고 점멸.. 너무 간단해서 설명이 필요 없네요.

/대상 Earthbind Totem
/대상 Searing Totem
/대상 용암 토템
/대상 Mana Spring Totem
/대상 Grounding Totem
/대상 Healing Stream Totem
/시전 !마법봉 발사
/targetlasttarget

설명 : 토템 제거용, 토템 영문명은 한글명으로 고쳐주셔야 작동할겁니다. 그리고 마법봉 발사는 !를 붙여놨는데 불필요하시다면 삭제하시길

#showtooltip
/cast [mod:ctrl,mod:alt]차원의 문: 스톰윈드; [mod:ctrl,mod:shift]차원의 문: 아이언포지; [mod:alt,mod:shift]차원의 문: 다르나서스; [mod:shift]순간이동: 아이언포지; [mod:ctrl]순간이동: 다르나서스; [nomod]순간이동: 스톰윈드

설명 : 설명 안드려도 될 듯.. mod키 지정한 포탈 매크로입니다. mod키로 어떤 키를 썼는지만 보시고 곧잘 쓰실 수 있으실 겁니다. 원래대로라면 6키가 필요한데 원키로 가능합니다.