그냥 매크로만 적으니 잘 모르시는 분들이 계셔서 일단 사제 매크로를 예로 설명을 추가합니다. 
다른 직업의 매크로들도 스킬조합은 다르지만 거의 유사한것들이 많습니다.

특성 1 - 수양사제(spec:1로 된것), 특성2 -암흑사제(spec:2로 된것)로 작성되었으며, mod 로 표시된것은 mod:shift,mod:ctrl,mod:alt를 모두 포함합니다. 

아래 같이 조건이 3개가 있을 경우, 조건1이 참이면 이후 조건2,3은 모두 무시되며, 순차적으로 적용됩니다.
즉 조건1이 거짓이고 조건2가 참이면 조건2일때 작동합니다. 조건문이 많아져도 기본 개념은 같습니다.

/시전 [조건1][조건2][조건3]스킬

* 추가 : 특성이 자신과 다르거나 반대일경우 자신에 맞게 수정이 필요하며, 반대일경우 spec:1을 spec:2로해야겠죠
스킬의 조합이 자신이 원하는 것과 다를 경우 본인의 입맛에 맞게 수정함은 필수입니다. 저랑 다른 유저분이랑 기호가 똑같진 않으니까요.잘 이해가 안가는 부분은 질문해주시면 답변해 드리겠습니다.


1. 결치와 순치

#showtooltip
/시전 [mod,@mouseover,help,nodead][mod,@focus,help,nodead][mod]결속의 치유;[@mouseover,help,nodead][help,nodead][@targettarget,help][@player]순간 치유

- nomod상태 즉 그냥 클릭시 순간치유가, mod시 즉 기능키(shift,atrl,alt등)를 누르고 클릭시엔 결속의 치유가 시전됩니다. 즉 크게 순치와 결치로 나누어진것을 합친겁니다. 

- nomod상태일때만 보면, 1순위가 마우스오버된 아군이 죽지않았을때, 2순위는 대상이 아군이고 살아있을때, 3순위는 대상의 대상(힐러일때 대상의 대상을 힐하거나 해제등 많이 씁니다)이 아군일때, 4순위로 앞의 모든 조건이 아닐땐 자신에게 순치를 시전하게 됩니다. 

- mod일때는 위 nomod와  같습니다. []안에 mod로 된 부분만 적용됩니다. 다만 조건이 약간 다른데, 1순위는 마우스오버인 살아있는 아군에게, 2순위는 살아있는 아군 주시대상에게, 3순위는 대상에게 결치를 사용하게 됩니다.
만약 자신의 입맛에 맞지 않다면 해당 부분만 수정하시면 됩니다.

2. 해제
#showtooltip
/시전 [mod]!대규모 무효화;[@mouseover,harm,nodead]마법 무효화;[spec:1,@mouseover,help,nodead][spec:1,help,nodead]정화;[harm,nodead][spec:2]마법 무효화;[@player]정화

- #showtooltip은 해당 스킬의 설명과 아이콘을 단축키에 표시해 주는 기능을 합니다.

- mod시엔 대규모 무효화를 시전합니다. 이때 스킬앞에 !가 있죠. 이걸 넣으면 2번눌러도 그라운드 타겟이 취소가 되지 않고 계속 유지됩니다. 즉 해당 스킬을 계속 발동 대기상태로 하라는 기능입니다.

- nomod시(즉 대규모 무효화만 mod가 있으니 이후의 조건문은 모두 nomod일때만 발동하게 됩니다.) 적대적대상이면 마법 무효화를 아군이면 정화를 사용하게 됩니다. 역시 []의 조건문 순서대로 거짓일시 다음 조건문이 수행됩니다.

- spec:1, spec:2라는 조건이 처음 나왔군요. spec:1이 있는 부분은 맨 위에 첨부된 것처럼 수양사제일때만 작동하며, spec:2가 있으면 당연히 암사일때만 작동하게 됩니다. 없으면 특성에 관계없이 모두 적용되죠.

- 한줄에 조건문이 많아도 순차적으로 시행된다는 것만 기억하시면 되겠습니다. 
뒤의 모든 매크로들이 이 순차조건문을 이용한것이 많습니다.

-아래 매크로는 위 매크로를 각각의 시전 명령으로 분리한 것인데, 똑같은 기능을 합니다. 
당연히 위처럼 줄여서 쓰는것이 좋겠죠?
 
#showtooltip
/시전 [mod]!대규모 무효화
/시전 [nomod,@mouseover,harm,nodead]마법 무효화
/시전 [spec:1,nomod,@mouseover,help,nodead]정화
/시전 [spec:1,nomod,help,nodead]정화
/시전 [nomod,harm,nodead]마법 무효화
/시전 [spec:2,nomod]마법 무효화
/시전 [@player]정화

3. 신의의 도약과 소실
#showtooltip
/연속시전 [mod,@mouseover,help,nodead][mod]신의의 도약;[spec:1]소실;[@player]reset=10 소실,소생,회복의 기원,신의 권능: 보호막

- 크게 mod시엔 신의의 도약을, 기본(nomod)시엔 소실을 쓰게 만들었습니다.
- spec:1 즉 수양일때는 소실만 쓰지만 암사일때는 자신에게만 소생, 회복의 기원, 보호막을 연속적으로 쓸수있게 되어있습니다. 10초간 해당키를 안누르면 초기화됩니다. 암사의 문양으로 소생과 회복의 기원을 형상시에도 사용가능하죠.  
- 위 처럼 연속시전에도 조건문을 여러개 두어서 사용가능합니다.   

4. 
#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/시전 [spec:1,mod]내면의 집중력
/시전 [spec:1,mod,@mouseover,help,nodead][spec:1,mod]치유의 기원;[mod,@mouseover,harm,nodead][mod]정신적 두려움;[spec:1,@mouseover,exists][spec:1]회개;[@mouseover,harm,nodead][]침묵

- "/적선택 [noexists][spec:2,noharm][dead]"은 대상이 없을 경우 아니면 암사인데 적대적대상이 아닌경우 또는 특성 관계없이 죽은 대상일경우 가까운 근처의 적을 자동으로 선택해 줍니다.
-spec:1 즉 수양사제일때, mod시엔 내면의 집중력과 치유의 기원을 동시에 써주게 되며, 내집이 쿨중이면 지기만 쓰게 됩니다. 내집이 글쿨이 없어서 가능합니다. 또 nomod시엔 회개를 쓰는데, 마우스오버에 exists가 붙었군요. 이건 적대적이던 아군이던 마우스오버대상이 존재하면 쓰라는 겁니다.
-spec:2 즉 암사일때는 mod시엔 정신적 두려움을 , nomod시엔 침묵을 쓰게 됩니다.

5. 어둠의 마귀
#showtooltip
/적선택 [noexists][noharm][dead]
/소환수공격
/시전 [pet,@pet]신의 권능: 보호막;[@mouseover,harm,nodead][]어둠의 마귀
/시전 흡혈의 선물
/사용 10
/사용 13

- 보통때는 어둠의 마귀를 1순위로 마우스오버대상에게, 2순위는 대상에게 써주며 마귀가 있을때 또 누르면 마귀에게 보호막을 줍니다. 가끔 마귀가 죽을거 같을때 써주면 됩니다. 10은 손에 기공마부가 있는 경우, 13은 첫번째 장신구를 써줍니다. 암사라면 흡선까지...

6. 생존기
#showtooltip
/시전 [spec:1,mod]신의 권능: 방벽;[spec:2]분산;[@mouseover,help,nodead][help,nodead][@targettarget,help][@player]고통 억제
/사용 14

- 수양사제일땐 mod시 방벽을, 보통때는 고억을 써줍니다. 암사일때 분산...
- 14는 두번째 장신구를 써주는 건데, 제 경우 급장이나 생존에 유용한 장신구를 넣기때문에 넣었지만 아닐경우 때시고, 물약이나 다른 생존에 유용한 스킬을 넣으셔도 됩니다. 보통 고억이나 방벽은 피가 많이 달아서 위험할때 쓰니 잘 넣어주면 상당히 도움이 됩니다.

7. 
#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/소환수공격 [@pettarget,noexists]
/연속시전 [spec:2,nomod]정신 분열;[@mouseover,help,nodead][help,nodead][@targettarget,help][@player]reset=1/target 소생,회복의 기원

- "/소환수공격 [@pettarget,noexists]" 간혹 마귀를 뽑았는데 놀고있는것을 방지해 줍니다.
- 이 매크로는 앞의 매크로와 약간 다른데, [spec:2,nomod]가 앞에 있습니다. 즉 암사이고 보통때만 정신분열을 쓰고, 암사인데 mod시엔 소생, 회복을 기원을 연속으로 써주게 됩니다. 그외 수양일때도 소생과 회복의 기원을 써주는데, 초기화시간이 1초입니다. 즉 연타해야 회기까지 들어가죠. 또한 대상이 변하면 소생이 계속 들어갑니다. 

8. 보호막과 탈것
#showtooltip
/시전 [mod]암흑질주;[nogroup,@player][@mouseover,help,nodead][help,nodead][@targettarget,help][@player]신의 권능: 보호막
/무작위시전 [mounted];[flyable]청동 비룡,푸른 비룡,백색 비룡,붉은색 비행 구름,황실 기렌,저주받은 기사의 군마;야생 질주,아마니 전투곰,날쌘 눈호랑이,거대한 가을 축제 코도,스톰파이크 전투산양
/탈것내리기
/내리기

- 내용이 많아서 복잡해 보이지만 크게 보호막과 탈것으로 되어있습니다. mod시엔 늑인이라 암흑질주를 넣었지만 기동이면 니트로를 이속기능이 없다면 빼시면 됩니다. [nogroup,@player]는 파티가 아닐때는 무조건 자신에게 쓰라는 겁니다. 
- 무작위시전은 이제 거의 탈것에만 쓰고 있습니다. [mounted];로 공백인데 승마시 특정스킬을 원하면 넣으시면 됩니다. 
그외 비승마시이고 날탈을 탈수있으면 [flyable]뒤에 자신의 날탈을 죽 넣어주시면 됩니다. 단 255자 제한을 넘기면 안됩니다. 조심하시고... [flyable]의 뒤에 ";"뒤에는 뛰어다니는 탈것을 넣어주세요. 위 매크로는 제가 원하는 탈것만 넣었으니 자신의 탈것을 shift+L 눌러서 shift클릭해 자기만을 탈것을 등록하세요. 이때 자기 캐릭이 탈수없는 탈것을 등록하면 매크로가 먹통 될수있습니다. 
- 탈것매크로의 경우, 글쿨이 없으며, 비전투시에만 사용되기 때문에 위처럼 보호막등과 조합해도 아무런 이상없이 사용가능합니다. 비전투시엔 보호막을 걸면서 날탈을 타주며, 전투시엔 보호막만 걸죠.

9. 언데드속박과 영혼의 절규
#showtooltip
/시전 [nomod]영혼의 절규;[@mouseover,harm,nodead][]언데드 속박
/사용 [nomod]13
/주시 [mod,@mouseover,harm,nodead][mod]

- mod시엔 속박을 걸면서 주시로 잡아주고, nomod시엔 영절을 써주고 첫 장신구를 써줍니다.
- "/주시 [mod,@mouseover,harm,nodead][mod]"는 자동으로 주시잡는것을 원하지 않으면 빼주세요.

10. 광역
#showtooltip 정신 불태우기
/적선택 [noexists][spec:2,noharm][dead]
/사용 [spec:2]10
/시전 [nochanneling:정신 불태우기]정신 불태우기

- 기공이면 손마부 써주고 정불을 써주며, 정불을 정신집중중이면 또 사용하지 않고 다 쓰면 쓰게 해줍니다.

11. 수양일때는 상치, mod시엔 내집과 동시에 써주며, 암사일때 형상이 아니면 형상으로 바꾸어주며, 형상시에만 정신의 쐐기를 써줍니다. [form:0]은 [stance:0]과 같으며, 전 form이 2자 적어서 form을 씁니다. form:0은 비형상시의, 즉 노멀상태의 태세입니다.

#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/시전 [spec:1,mod]내면의 집중력
/시전 [spec:2,form:0]어둠의 형상;[spec:2]정신의 쐐기;[@mouseover,help,nodead][help][@targettarget,help,nodead][@player]상급 치유

12. 죽음 - 시전중지가 들어간것 외엔 다를게 없군요.

#showtooltip 어둠의 권능: 죽음
/적선택 [noexists][noharm][dead]
/시전중지
/사용 [combat]10
/시전 어둠의 권능: 죽음

13. 수양시엔 치유, 암사일때 파멸의 역병..

#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/시전 [spec:2,form:0]어둠의 형상;[spec:2]파멸의 역병;[@mouseover,help,nodead][help][@targettarget,help,nodead][@player]치유

14. 수양일때는 회복의 기원을, 암사일땐 nomod시에 정신의 채찍을 mod시엔 회복의 기원을 사용합니다.
"/매크로중지 [channeling]"는 정신집중시엔 매크로를 중지하라는 것입니다.

#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/매크로중지 [channeling]
/시전 [spec:2,nomod]정신의 채찍;[@mouseover,help,nodead][help,nodead][@targettarget,help,nodead][@player]회복의 기원

15. 조금 복잡합니다만, 크게 암사일때는 고통, 흡손을 연속시전으로 쓰게 해주고, 수양사제일때는 성스러운일격을 써주다가 신불이 쿨이 오면 신불을 자동으로 써주는 매크로입니다.  매크로 특성상 칼 타이밍에 신불이 들어가진 않으며, 연타해야만 제대로 작동합니다.  사용해보시면 대충 감이 오실겁니다.

#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/연속시전 [spec:2,mod]흡혈의 손길;[mod][spec:2]reset=3/target 어둠의 권능: 고통,흡혈의 손길;[harm,nodead][@targettarget,harm,nodead][]성스러운 일격
/매크로중지 [mod]
/시전 [harm][@targettarget,harm]신성한 불꽃

16. 그냥 스킬 모음...
#showtooltip
/적선택 [noexists][spec:2,noharm][dead]
/시전 [mod]희망의 찬가;[spec:1]대천사;흡혈의 선물