단축키 슬롯 많이 부족하시죠...
제가 쓰는 매크로입니다.

뻔한 것들도 있지만.. 
비슷한 질문이 자주 올라오고..
가끔 대상/주시대상 매크로에 일일이 단축키 지정하는 분들이 계시길래..

도움이 될까 해서 올려봅니다..





전제사항으로


1. 양손무기와 검방만 따로 빼서 장비지정을 해주셔야 합니다. (와우 기본기능)
전 [양손] 과 [검방] 이란 이름으로 저장해뒀습니다.

모르시는 분들은 예전 글을 참고하세요..


2. 제 경우 기본 주시대상에게 시전 키를 ctrl로 사용합니다.
but 매크로의 경우 주시대상 키가 먹히질 않습니다. 그래서 따로 지정해줘야 하지요.
그래서 대부분 매크로의 mod:ctrl 기능은 주시대상에게 시전 기능입니다..











#showtooltip 돌진
/시전 [nomod:ctrl,@mouseover,exists,harm][nomod:ctrl,@target,exists,harm][mod:ctrl,@focus,harm,exists]돌진
/시전 무력화
/오라취소 칼날폭풍
/오라취소 보호의 손길

연타하면 칼폭, 보축이 취소되고 돌진합니다.

1. 마우스오버 대상이 적이면 돌진
2. 대상이 적이라면 돌진
3. ctrl 누르고 쓰면 주시대상에게 돌진
- 대상이 근접할 시 무력화 (취향에 따라 분쇄 넣으세요.)











#showtooltip 자루 공격
/시전 [nomod:ctrl,@mouseover,exists,harm][nomod:ctrl,@target,exists,harm][mod:ctrl,@focus,harm,exists]자루 공격
/시전 [mod:ctrl,@focus,harm,exists] 돌진
/오라취소 칼날폭풍
/오라취소 보호의 손길


그냥 쓸때 : 대상에게 깡마
ctrl 누를때 : (주시대상이 멀면) 주시대상에게 돌진 - (주시대상이 가까우면) 주시대상에게 깡마

누르면 칼폭과 보축이 취소됩니다.
걍 주시차단 편하라고 해본거..









#showtooltip 가로막기
/시전 [target=mouseover,help][target=target,help][target=focus,help][target=targettarget,help][target=party1] 가로막기
/시전 방어 태세


1. 마우스 오버한 대상이 아군이라면 가막
2. 대상이 아군이라면 가막
3. 주시대상이 아군이라면 가막
4. 대상의 대상이 내가 아닌 아군이라면 가막
5. 파티원 1에게 가막(22 투기장 용)

입맛에 맞게 적절하게 순서 바꿔서 쓰시면 됩니다.







#showtooltip 
/시전 [nomod]영웅의 투척
/시전 [mod:alt,nostance:2] 방어 태세 
/시전 [mod:alt] 도발
/시전 [mod:ctrl,@focus]영웅의 투척


1. 대상에게 영투깡마
2. ctrl 키 누를시 주시대상에게 깡마
3. alt 키 누를시 방태전환 후 대상에게 도발(ex펫) 

걍 힐러 괴롭히는 펫 도발 할때 쓰려고 묶었습니다.. 








#showtooltip
/시전 위협의 외침
/예약취소
/cleartarget
/targetenemy [noexists]
/시전 위협의 외침


가끔 대상 사정거리땜시 위협이 안나가거나 
위협 연타했는데 글쿨 막바지에 걸려 다른기술이 나가거나 할때 있져..

예약취소로 다음 예약스킬을 취소하고
자신의 앞 가장 가까이 있는 적을 자동으로 선택해서 바로 위협이 발동되도록 해줍니다.

근데 잘못쓰면 힐러타겟으로 써버려서 힐러가 그자리에서 벌벌 떨므로 주의 ㅋ
내 직선 앞에 가장 가까운 타겟에게 써집니다.







#showtooltip 무장 해제
/예약취소
/targetenemy [noexists]
/공격시작 [exists]
/시전 방어 태세
/시전 [nomod,@target]무장해제
/시전 [mod:ctrl,@focus]무장해제


위협과 마찬가지로 스킬 예약을 취소해서 다른 기술이 나가지 않도록 하고..
급히 타겟을 바꾸고 쓸때 자동공격이 취소되는 경우를 고려해서
분노가 모자를때 바로 한대치고 넣을 수 있도록 자동공격을 넣었습니다.

그냥 쓸때 : 대상에게 무장해제
ctrl을 누를때 : 주시대상에게 무장해제








#showtooltip 분쇄의 투척
/예약취소
/오라취소 칼날폭풍
/오라취소 보호의 손길
/시전 전투 태세
/시전 분쇄의 투척

칼폭 돌다 법사놈이 얼방을 썼다 핑크게이놈이 무적을 넣어줬다 
바로 연타해주심 됩니당..









#showtooltip 주문 반사 
/targetenemy [noexists]
/공격시작 [exists]
/equipset [noequipped:방패]검방
/cast [stance:1/2] 주문 반사;[stance:3] 전투 태세
/시전 지휘의 외침

1. (방패를 안끼고 있다면) 검방스왑 - (전태, 방태일때) 주문반사 - (광태일때) 전태

분노가 모자라는 경우를 고려해 지휘 외침을 넣었습니다.. 
요건 입맛대로..










#showtooltip [stance:1/3,nomod:alt]마무리 일격; [mod:alt] 방패 막기; [stance:2] 방패 막기;
/targetenemy [noexists]
/공격시작 [exists]
/equipset [noequipped:방패,mod:alt] 검방
/cast [mod:alt] 방어 태세
/매크로중지 [nocombat]
/시전 방패 막기
/equipset [equipped:방패,nomod] 양손
/cast [nostance:3] 광폭 태세
/시전 [nostance:2] 마무리 일격


1. 그냥 누르면 : (방패를 끼고있을때)양손무기 스왑 - (방태일때) 광태전환 - 대상에게 마무리일격 
2. alt를 누르면 : (방패를 안끼고 있을 때)검방 스왑 - (전태,광태일때) 방태전환 - 방패막기
- 비전투중 : 검방 스왑후 방어태세

제가 방특,딜특일때 마격과 방막을 같은 단축키에 두고 쓰는 습관이 있어서 묶은건데..

평소엔 그냥 마격으로 쓰시고
투기장에서 방벽을 아끼고 잠깐 버텨야할때 alt 누르고 쓰시면 검방스왑 방태전환 방막이 나갑니다.
다시 그냥 누르면 양손무기 스왑후 광태전환 마격(전태이면 그냥 바로 마격)이 나가구요.

비전투시 분노여부와 상관없이 방태-검방스왑이 됩니다.
투기장 시작시 상대가 은신클래스로 물리고 시작하겠다 싶을때 살포시 alt와 함께 눌러주심 됨..


(마격을 그냥 전태로 쓴다! 하시는 분은 
/cast  [nostance:3] 광폭 태세 <- 이부분을 [stance:2] 로 하심 됩니다.)










#showtooltip
/시전 [nomod:alt]영웅의 일격;[mod:alt]회전베기
/시전 [mod:alt]휩쓸기 일격
/시전 연전연승


1. 그냥 누르면 영웅의 일격
2. alt를 누르면 휩쓸기 일격 + 회전베기
- 연전연승이 활성화 되어있다면 연전연승









#showtooltip
/targetenemy [noexists]
/공격시작 [exists]
/시전 [nomod:alt]제압; [mod:alt]분쇄


1. 그냥 누르면 제압
2. alt키를 누르면 분쇄

사족으로 대상이 없으면 대상잡고 자동공격 시작도 추가했습니다..
가끔 타겟전환하고 분쇄 넣어야되는데 
대상 바뀌면서 자동공격이 풀려 분노가 없어 못넣는 경우도 있더라구요..









#showtooltip 거인의 강타
/예약취소
/equipset [equipped:방패] 양손
/시전 [stance:2] 전투 태세
/시전 거인의 강타
/매크로중지 [nocombat]
/사용 10
/사용 13


1. (방태라면)전태스왑(광태는 유지) - (검방이라면)양손무기 스왑 - 장신구 돌리고 - 거인의 강타
- 비전투시 : 분노,장신구 쿨 여부와 상관없이 양손무기 스왑후 전투태세만

방막매크로처럼 비전투시 양손-전태 전환으로 쓰시면 되고
전투시엔 주반,방벽,무장해제 등 검방스왑-방태 상태 이후에 
전태-양손무기로 돌아오는 용도로 쓰시면 됩니다.

장신구는 취향껏 지우세요.. 전 안써요..






#showtooltip 칼날폭풍
/예약취소
/시전 휩쓸기 일격
/시전 칼날폭풍


휩쓸기+칼폭
칼같이 뽑기위해 예약취소도 넣었습니다.

(사실 예약취소는 글쿨이 도는 모든 스킬에 유용합니다.
예약시전기능을 꺼버리기엔 스킬 사이 글쿨이 낭비되고
그렇다고 연타하자니 힘들고..

칼같이 써야하는 기술들의 매크로엔 
맨앞단에 예약취소를 넣어주시는게 좋습니다. 씹히지 않게..)










점점 너무 뻔한 매크로들만 나오네요...









#showtooltip
/targetenemy [noexists]
/공격시작 [exists]
/cast [nomod:alt] 천둥벼락; [mod:alt]사기의 외침


1. 그냥 누르면 천둥벼락
2. alt 누르면 사기의 외침







#showtooltip
/오라취소 내면의 분노
/매크로중지 [nocombat]
/시전 죽음의 침묵
/사용 13
/사용 10


1. 내면의 분노 취소후 죽음의 침묵 + 장신구
- 비전투시 안나감







#showtooltip [nomod:alt]무모한 희생; [mod:alt]내면의 분노;
/매크로중지 [nocombat]
/사용 13
/사용 10
/시전 내면의 분노
/시전 [nomod]무모한 희생


1. 그냥 누를시 : 무모한 희생+내면의 분노+장신구
2. alt 누를시 : 내면의 분노+장신구만 시전
- 비전투시 안나감









#showtooltip 방패의 벽 
/오라취소 칼날폭풍
/stopcasting
/시전 지휘의 외침
/equipset [noequipped:방패] 검방
/시전 방어 태세
/시전 방패의 벽
/시전 방패 막기


1. 칼폭취소 - (지휘외침) - 검방스왑 후 방태-방벽-방막

칼폭, 분쇄나 격돌 시전중이면 취소하고 바로 사용됩니다.. 
지휘와 다른기술들이 글쿨이 같이 돌지않아 모두 즉시시전 됩니다.








#showtooltip [mod:alt] 격노의 재생력; [nomod]재집결의 함성;
/시전 [nomod]재집결의 함성
/시전 광전사의 격노
/시전 격노의 재생력
/사용 생명석


1. 그냥 누르면 재집결-광격-격재-생명석
2. alt 누르면 광격-격재-생명석

- alt키 누르면 격재 쿨을 확인 가능합니다.. 
근데 전 나눠서 잘 안쓰게 되더라구요.. 피 채울수 있을때 같이써야지..





#showtooltip
/시전 [nomod] 지휘의 외침
/시전 전투의 외침

1. 그냥 누르면 지휘외침
2. alt는 전투외침








쓰다보니 정신이 혼미해지네여..

이 외에.. 보복이나.. 쓰트같은건 그냥 기본 주시대상에게 시전키(ctrl)와 함께 쓰시면 되고..
이정도만 묶어쓰셔도 슬롯 한두개 남습니다..

전사님들 퐈이팅..










***** 그외.. 


#showtooltip 도발
/시전 [stance:2][@mouseover,harm][@target,harm] 도발
/시전 [@target,help][@targettarget,help] 경계 

먼저 도발은

1. 마우스 오버한 대상이 적이면 도발
2. 대상이 적이면 도발

경계는..

1. 대상이 아군이라면 경계
2. 대상의 대상이 아군이라면 경계 
(ㄴ 아군에게 적이 뛰는데 도발이 쿨일때.. 
자동으로 경계가 들어가고 한대 맞자마자 도발쿨이 초기화되서 땡길 수 있습니다.
허나 잘 안쓰입니다.. 요즘엔 어글이 잘 안텨서.. 베스틸락 쫄처리때 쓰면 좆망이니 적절히 수정 ㅋ)







#showtooltip
/매크로중지 [noexists]
/cast [equipped:투척 무기]투척; 발사 
/script SetRaidTarget("target", 8) 
/ㄷ [%t] 풀링합니다. 해골 우선 점사..

1. 타겟에 해골마크를 찍고 점사대사를 출력하고 - 투척으로 풀링합니다.
- 대상이 없으면 대사가 안뜹니다.







검방스왑 매크로

/equipset [noequipped:방패] 검방
/equipset [equipped:방패] 양손

누를때마다 서로 전환됩니다.









전사님들 퐈이팅..