<<들어가며>>


1. 매크로는 만능이 아닙니다. 

  원하는 스킬이 '허용된 설정내의' 주어진 조건에서 작동되게끔 하는 것이 매크로의 목적입니다. '허용된 설정'에는 예를 들어 현재 타겟이 무엇인가(적/아군), 마우스오버 대상이 존재하는가, 어느 대상을 우선으로 스킬을 사용할 것인가 등, 해당 기술이 사용될 상황과 그 적용대상이 주된 내용입니다.


2. 적절한 애드온과 함께 사용하시는 것이 유익합니다. 

  예를 들어 대상에게 스킬이 들어갔음을 알리는 것은 매크로로도 스크립트 짜는게 가능하지만, Detail 등의 알림 기능이 훨씬 간명합니다. 아울러 매크로 길이도 짧아지죠. 힐러는 적절한 레이드프레임, 탱커라면 어그로미터기 등... 매크로의 한정된 기능을 보완/개선하는 애드온들이 많습니다. 와우의 끝은 순정이 아니라고 생각합니다. 보다 더 쓸만한 애드온이죠.


3. 한 스킬은 한 스킬버튼만을 사용한다. 단, 매크로로 적용하는데 한계가 있을 경우엔 따로 단축키를 배정할 것.

  매크로는 255자의 제한이 있습니다. 케릭별 매크로는 18개로 제한되고요. 도적이나 악사처럼 스킬이 적은(효용성은 별개로) 클래스는 상황매크로를 적용해도 칸이 널널합니다.
  그러나 하이브리드 클래스(힐/지원 되는 딜러, 또는 딜/지원되는 힐러 등)들은 원하는 상황에 원하는 키를 눌러 원하는 스킬을 쓰기 위해선 매크로칸 18개로 한참 부족합니다. 따라서 매크로 버튼 하나에 가능한 한 조건문을 때려박아야할 필요가 있죠. 
  매크로는 동작을 간소화하기 위함 뿐만이 아니라, 단축바의 버튼수를 줄여주는 역할도 합니다. 그렇지만 상정하지 않은 변수가 발생할 수 있는 게임 내 환경에서 매크로의 문제가 발생하기도 하죠. 그럴땐 편하게 단축키 하나 더 넣어주세요. 다행히도 와우 내 스킬버튼은 넉넉합니다. 서두는 이정도로 말씀드릴게요.



<<성기사 매크로>>


1. 성기사의 전문화(spec)는 1=신성, 2=보호, 3=징벌 입니다. 앞의 조건문에 spec:1 또는 spec:2 이 포함된 경우 spec:3 은 필요가 없는 경우가 대부분입니다. 앞 조건에서 다 걸러지기 때문입니다.

2. 공용 스킬의 조건문 우선순위가 있습니다. 예를 들어 신성기사는 성격보다는 빛섬을 더 자주 사용... 하지는 않더라고요. 요즘엔 자락신기가 대세라. 그러나 만렙 이후의 이야기일 뿐, 그 이전까지의 클래식 신기의 경우 빛섬이 최우선, 성격이 차순위입니다. 따라서 두 스킬을 묶을 경우 우선순위는 빛섬이 됩니다. 당면한 상황의 스킬 시전 우선순위에 따라 조건문이 앞에 오는지, 위로 가는지가 결정됩니다.

3. 밑의 목록을 보시면 아시겠지만, 저는 3전문화 모두 하고 있습니다. 한두가지 하시는 분들은 매크로의 길이가 필요 이상으로 길기 때문에 해당 전문화 번호가 들어간 조건문을 삭제하시면 보다 관리하기 편하실거라 생각합니다.


#showtooltip
/targetenemy [noexists]
/시전 [@mouseover,exists,nodead,spec:1][spec:1] 신성 충격; [@mouseover,harm,nodead,spec:2][spec:2] 응징의 방패; [@mouseover,harm,nodead][] 심판의 칼날;

  전문화별 주력스킬1 매크로 입니다. 기본적으로 타겟이 없을 경우, 가까운 적을 대상으로 합니다(꼭 그렇지 않은 경우도 있더군요). 마우스오버 대상에 우선적으로 1)신기일때 신충, 2)보기일때 응방, 3)징벌일때 심칼을 사용합니다. 마우스오버 스킬이 먹통인 경우가 보통 조건문에 nodead를 넣지 않아 마우스커서가 시체 위에 있을때 스킬이 사용되지 않는데, 그것을 방지합니다.


#showtooltip
/오라취소 천상의 보호막
/시전중지
/시전 천상의 보호막

  너무 기본적인 매크로죠. 한번 누르면 천보, 다시 한번 누르면 천보 취소입니다. 가끔씩 순서를 바꾼 매크로를 공유하는 경우를 봤는데, 이 경우 천보 시전하자마자 꺼집니다. 보호기사라면 필요할 수도 있겠네요. 괴저중첩을 푼다든지...(보축쓰죠 요즘엔)


#showtooltip
/clearfocus [dead]
/시전중지
/시전 [@mouseover,harm,nodead][@focus,harm,nodead][] 비난

  차단 매크로입니다. 주시대상이 있고 적일 경우 현재 대상보다 우선적으로 주시대상에게 비난을 넣습니다. 그러나 마우스오버 대상이 있고 적일 경우 주시대상보다 우선적으로 마우스오버 대상에게 비난을 넣습니다. 중간의 시전중지 부분은 삭제하셔도 무방합니다. 징기는 시전할게 빛섬이랑 구원밖에 없으니까요.


#showtooltip
/targetenemy [spec:3,noexists]
/사용 [@mouseover,help,nodead,spec:1][spec:1] 성스러운 빛;[@mouseover,help,nodead,spec:2][spec:2] 수호자의 빛;[@mouseover,harm,nodead][] 기사단의 선고

  전문화별 주력스킬2 매크로 입니다. 물론 요즘엔 성빛 잘 안쓰기는 합니다만, 안그래도 휑한 단축창에 구색은 맞춰줍니다. 1)신기일때 성빛, 2)보기일때 수빛, 3)징기일때 선고 넣습니다. 수빛의 경우 수손 특성을 찍을 경우 알아서 마우스오버 대상에 수손을, 없을 경우 자신에게 사용합니다. 보기 할때 적 대신 아군을 대상으로 하는 경우, 잘 없죠?


#showtooltip
/cleartarget [dead]
/시전 [@mouseover,help,nodead] 빛의 섬광; [@mouseover,harm,nodead][harm] 성전사의 일격; 빛의 섬광 
/targetenemy [noexists]

  약간 의아하실 수 있는 매크로입니다. 기본적으로 노타겟시 빛섬을 자신에게 꽂습니다. 대상이 적일 경우 성격을 넣고 마우스오버 대상이 아군일 경우 최우선적으로 빛섬을 넣습니다. 거기에 추가로, 사냥할때 적을 죽여놓고 루팅을 한 경우, 이 매크로를 한번 누르시면 자신에게 빛섬 넣고 주변의 적을 자동으로 타게팅합니다.


#showtooltip
/시전 [@mouseover,harm,nodead] 심판의 망치;[@mouseover,help,nodead,spec:1][help,spec:1] 정화;  [@mouseover,help,nodead,spec:2/3][help,spec:2/3] 독소 정화; [] 심판의 망치;

또는

#showtooltip
/시전 [@mouseover,help,nodead,spec:1] 정화; [@mouseover,help,nodead] 독소 정화;[@mouseover,harm,nodead][harm] 심판의 망치; [spec:1] 정화; [] 독소 정화; 

  심망과 정화를 묶은 매크로 입니다. 선호에 따라 하나 골라서 사용하세요. 이 경우 자신에게 정화 또는 독소 정화를 쓰고 싶은데도, 적을 타겟하고 있어서 사용하지 못하는 경우가 있습니다. 이때는 바로 아래의 매크로를 사용해보세요.


#showtooltip
/시전 [@mouseover,help,nodead,spec:1][spec:1] 정화; [@mouseover,help,nodead][] 독소 정화;

  마우스오버가 우선이며 대상이 아군이면 아군에게, 대상이 적이면 자신에게 정화/독소 정화를 시전합니다. [@targettarget,help,nodead] 조건문은 의미가 없더군요. 보통은 성격치느라 타겟을 언제나 적으로 두기 때문이죠.


#showtooltip
/시전 응징의 격노
/시전중지
/사용 [spec:1/2][spec:3,notalent:7/2] 13

  응격 매크로입니다. 보통 저는 윗 장신구 칸에 사효, 아랫 장신구 칸에 착효를 넣습니다. 때문에 장신구 번호 13을 적용합니다. 아랫 장신구 칸은 14 입니다. 이 매크로는 성전 찍은 징기일땐 장신구를 사용하지 않습니다.


#showtooltip
/stopmacro [@mouseover,help,dead,combat]
/시전 [nocombat,group,spec:1] 사면; [@mouseover,help,nodead,combat][combat] 신의 축복; [@mouseover,help,dead][] 구원;

  신축과 구원을 묶었습니다. 신축은 전투중 아니면 쓸 일이 없고, 구원은 징기 중에 궁극의 응직을 찍은 경우 아니면 전투 중에 쓸 일이 없습니다. 그래서 묶었죠.
  신기이고 파티/공격대 참가중이면 사면을 우선으로 사용합니다. 전투중일 경우 스킬이 신축으로 바뀌어 마우스오버(아군)/대상(아군)/자신 순으로 신축을 사용합니다. 비전투 중일 때 구원을 사용합니다. 
  이때, 신축을 사용하려다가 대상이 먼저 죽어버리면 자신에게 신축을 시전해버려 낭패를 볼 경우가 있습니다. 위의 stopmacro 구문은 그 상황을 방지해줍니다. 대신, 신축은 꼭 레이드 프레임 또는 대상에 마우스를 가져다 두실 필요가 있습니다. 보통 대상이 죽으면 타켓팅이 풀리고, 타겟이 없으면 자동으로 스킬이 들어가기 때문인데요. 저도 이 조건문을 어떻게 개선해보고 싶은데 아직은 무리입니다.



<<매크로 작성 패턴>>

위의 예시로 보여드린바 대로, 매크로는 패턴이 있습니다.

#showtooltip
/시전 [@mouseover,help,nodead][] 스킬명;

#showtooltip
/시전 [@mouseover,harm,nodead][] 스킬명;

#showtooltip
/시전 [@mouseover,harm,nodead] 스킬명1; [@mouseover,help,nodead][help] 스킬명2; 스킬명1

#showtooltip
/시전 [@mouseover,help,nodead] 스킬명1; [@mouseover,harm,nodead][help] 스킬명2; 스킬명1

마우스오버/대상이 적인지 아군인지에 따라 스킬이 달라지는 매크로는 3번과 4번째 패턴으로 커버 가능합니다. 좀 더 응용하면 전문화별/전투여부 등으로 더 세세하게 조건설정이 가능하지요.

아군에게도 적군에게도 사용할 수 있는 스킬이 있는 경우 어떻게 할까요? 신기에게는 신성 충격이, 수사에게는 회개가 있습니다. 이 경우,

#showtooltip
/시전 [@mouseover,exists,nodead][] 신성 충격

이 매크로문을 사용하시면 됩니다. 만약 신충을 자신에게 우선적으로 사용하고 싶다 하시면

#showtooltip
/시전 [@player,mod:ctrl][@mouseover,exists,nodead][] 신성 충격

ctrl키를 누른 상태에서는 본인에게 우선적으로, 그리고 마우스오버/대상/자신 순으로 신충이 사용됩니다.


------------------------------------------------------------------------------------------------------------

제가 이 글을 쓰게된 이유는 공지글 매크로에 오류가 꽤 있기 때문입니다. 아울러 한가지 보여드릴게 있구요.

#showtooltip
/시전 [target=mouseover,help][help][targettarget=help][target=player] 스킬명 

오리때부터 나온 유서깊은(?) 매크로 입니다. 이걸 줄여볼게요.

#showtooltip
/시전 [@mouseover,help][] 스킬명

이상입니다. 물론 되도록이면 nodead 구문을 넣어주세요. 마우스오버 대상이 시체일 경우 매크로가 먹통이 됩니다.


P.S/ 혹시라도 매크로 작성에 도움이 필요하신 분은 리플 달아주시면 최대한 성실하게 같이 고민해드리겠습니다.