1편 : https://www.inven.co.kr/board/wow/40/122986


지난 글에서는 매크로의 기본 동작방식과 간단한 논리연산에 대해 적었습니다
이번에는 매크로 작성시에 자주 문제가 되는 부분과 응용에 대해 적어보고자 합니다



1. 매크로 동작이 이상해요!

#showtooltip
/cast [@mouseover,help][help][] 회복
/cast [form:1] 후려갈기기 
------------------------------
#showtooltip
/cast [form:1] 후려갈기기
/cast [@mouseover,help][help][] 회복


먼저 가장 자주 발생하는 문제는 >> [ ] << 이 녀석입니다
괄호 안에 아무것도 없을 때에는 매크로가 "무조건"이라고 인식하게 됩니다
그리고 현재 타겟을 자동으로 인식하는 스마트 기능도 붙어 있습니다
회복을 예시로 들면, 적 타겟으로 잡고 회복을 사용하면 적 대상에게 사용이 불가능하니 자동으로 자기 자신에게 시전됩니다
아군 타겟이라면 아군에게 시전됩니다


그래서 첫번째 예문에서는 회복 조건식 끝에 [] (무조건)이 붙어있기 때문에 아랫줄로 내려가지 못하고 항상 회복이 시전됩니다
- 대상이 적이면 자신에게, 대상이 아군이면 아군에게


두번째는 매크로의 순서입니다
첫 줄에서 곰폼 체크를 해서 TRUE가 되었기 때문에 후려갈기기만 사용이 됩니다
그런데 [] 의 스마트 타겟 기능으로, 아군 타겟을 잡으면 후려갈기기 사용이 안되니 다음줄로 넘어가서 회복이 시전되죠
그래서 더 혼란이 오는겁니다
작동이 되는것도 안되는것도 아닌 묘한 상황처럼 보이게 되는거죠


그래서 원하는 방식으로 정리하면 이렇게 됩니다
  1. 마우스오버(아군) 회복
  2. 아군 회복
  3. 적 대상 and 곰폼일때 후려갈기기

#showtooltip
/cast [@mouseover,help][help] 회복
/cast [form:1] 휘둘러치기 

이렇게 >> [ ] << 이 구문 하나로 차이가 발생하게 됩니다
매크로를 작성하실 때, 동작이 이상하다면 확인해 보시기 바랍니다



2. 변신 풀림을 방지해 보자
곰/표범 상태의 스킬과 힐 스킬을 묶을 경우, 원치않는 타이밍에 변신이 해제되는 불상사가 발생할 위험이 있습니다
이를 방지하는 꼼수를 알아봅시다
하는김에 꽁재생 사용 중 변신풀림도 추가해 보죠

#showtooltip
/castsequence [mod,@player] reset=1 재생,null
/cast [spec:2/3,form:1/2] 휘둘러치기
/stopmacro [spec:2/3,form:1/2]
/cast [@mouseover,help][noform:1/2/4,help] 재생
/cast [noform:1/2] 천벌
/cast [form:1/2] 휘둘러치기 

뭔가 내용이 많습니다
차례대로 나열해 보면 이렇습니다


먼저 첫번째 줄의 연속시전(cast sequence) 구문은 다음과 같습니다

/연속시전 [옵션] 리셋타임 사용스킬(여러개 설정 가능)
[mod] = Ctrl, Alt, Shift 옵션키 중 아무거나 눌렀을 때 반응
[mod:ctrl] = Ctrl 키에만 반응

리셋타임이란?
해당 매크로 키를 누르지 않은 상태에서 설정한 초(sec)가 지나면 처음으로 돌아간다

그래서 첫번째 줄은
1. 옵션키 중 아무거나 눌렀을 때
2. 자기 자신(@player) 대상으로
3. 재생 -> 아무것도 안함 을 반복한다
4. 매크로를 누르지 않으면 1초 뒤 재생부터 다시 시전된다

null이 생소할 수 있는데, 그냥 '눌러도 아무것도 안한다' 라고 생각하시면 됩니다
그래서 위 매크로를 꽁재생이 떴을 때 연타하면 재생 -> 아무것도 안함이 되어서 변신이 풀리지 않게 됩니다
그리고 해당 매크로 키 라는 것은 정확히는 해당 구문에 적용되기 때문에 아래쪽 매크로가 막히지 않고 동작합니다


두번째 줄은 야드 or 수드 전문화이고, 곰 or 표범 폼일때 휘둘러치기를 사용하는 부분입니다
세분째 줄이 바로 변신풀림 방지 부분으로, 매크로 중지(stop macro)라는 구문입니다

/stopmacro [옵션] 

뜻 그대로 정해진 옵션에 걸리면 매크로 작동을 중지, 더 정확히는 해당 구문 아래에 있는 내용들을 무시하는 기능입니다
그래서 야드 or 수드이고, 곰 or 표범일때엔 마우스오버(아군)이나 아군 타겟을 잡아도 재생이 시전되지 않도록 방지합니다


그리고 예문을 보면 휘둘러치기가 2번 들어가 있는데, 윗줄의 휘둘러치기를 폼 상태만 주게 되면 회드일때 변신을 풀어야만 힐 시전이 가능하기 때문에 그렇습니다

#showtooltip
/castsequence [mod,@player] reset=1 재생,null
/cast [form:1/2] 휘둘러치기    <= 이렇게 해 놓으면 회드일때 변신 상태에서 힐 시전이 안된다!!
/stopmacro [spec:2/3,form:1/2] 



3. 변신 상태일땐 정상인데 인간(noform)일때 작동을 안해요!
다음 예문은 급속성장, 포효, 흉포한 이빨, 별똥별을 하나로 묶어서 동작합니다
그런데 실제 적용해보면 인간 상태에서 대상을 잡지 않으면 급속성장 캐스팅이 안됩니다
그렇다고 >> [ ] << 이 녀석을 넣으면 무조건 급속 성장만 나가게 되겠죠

#showtooltip
/cast [@mouseover,help][help] 급속 성장
/cast [form:1] 포효
/cast [form:2] 흉포한 이빨
/cast [form:0/4] 별똥별 

  1. 마우스오버(아군) or 아군 = 급속성장
  2. 곰폼 = 포효
  3. 캣폼 = 흉포한 이빨
  4. 빼미 = 별똥별

여기에 "대상이 아무도 없을때"라는 조건이 없다 보니 우리의 컴퓨터는 그대로 패스해 버립니다
실제 플레이에서 엄청 큰 지장이 있는건 아니지만, 그래도 그 한번의 '엇'하는게 시클과 소진을 가르니 보완해봅시다

#showtooltip
/cast [@mouseover,help][help] 급속 성장
/cast [spec:4,form:0/3] 급속 성장   <<== 추가
/cast [form:1] 포효
/cast [form:2] 흉포한 이빨
/cast [form:0/4] 별똥별  

다른 전문화에서 방해가 되지 않도록 [spec:4] (회드)임을 명시해 줍니다
다른 폼에서는 각 설정된 스킬이 발동할 수 있도록 인간과 날쌘동물만 설정해 줍시다 ([form:0/3])

여기서 헷갈리는 부분은 마지막 줄의 별똥별입니다
똑같이 인간 ([form:0])이 설정되어 있는데 문제가 안되나요?
네, 그래서 급속성장에는 [spec:4](회드)를 조건으로 걸어둔 겁니다

그럼 다른 전문화에서는 급속성장 사용 못하나요?
첫번째 줄 때문에 아군 대상을 잡으면 시전 가능합니다



드루이드는 폼변이 있다 보니 타 직업군 대비 매크로 작성에서 고려할 부분이 더 많은게 사실입니다
항상 아래 내용을 염두에 두고 구조를 설계하면 대부분 원하는 대로 작동하는 매크로를 만들 수 있습니다

모든 매크로 동작의 우선순위는
1. 왼쪽에서 오른쪽으로
2. 위에서 아래로 

제 회드 기준 매크로를 통한 스킬 변화 스샷과 사용중인 매크로 몇가지를 첨부합니다
다들 매크로의 세계에 발을 담궈봅시다

감사합니다





(부캐라서 없는 스킬이 좀 있네요)



차단기 모음집
#showtooltip
/cast [spec:4,@mouseover,help][spec:4,form:0/3] 숲 수호자
/cast [spec:1,noform:1/2] 태양 광선
/cast [form:1/2] 두개골 강타 


주력기 모음 1
#showtooltip/cast [spec:2/3,form:1] 후려갈기기
/cast [spec:2/3,form:2] 칼날 발톱
/stopmacro [spec:2/3,form:1/2]
/cast [@mouseover,help][noform:1/2/4,help] 회복
/cast [noform:1/2] 태양섬광
/cast [form:1] 후려갈기기
/cast [form:2] 칼날 발톱 


주력기 모음 2 + 꽁재생 변신풀림 방지
#showtooltip
/castsequence [mod,@player] reset=1 재생,null
/cast [spec:2/3,form:1/2] 휘둘러치기
/stopmacro [spec:2/3,form:1/2]
/cast [@mouseover,help][noform:1/2/4,help] 재생
/cast [noform:1/2] 천벌
/cast [form:1/2] 휘둘러치기 


주력기 모음 3
#showtooltip
/cast [spec:4,@mouseover,help][spec:4,noform:1/2/4,help] 피어나는 생명
/cast [noform:1/2] 별빛섬광
/cast [form:1] 짓이기기
/cast [form:2] 갈퀴 발톱 


#showtooltip
/cast [spec:1/2/3,mod,@player] 해제; [spec:4,mod,@player] 자연의 치유력
/cast [spec:1/2/3,@mouseover,help] 해제; [spec:4,@mouseover,help] 자연의 치유력; [harm] 휘감는 뿌리; [spec:1/2/3] 해제; [spec:4] 자연의 치유력 


특성에 따라 (보통 동시에 포인트를 투자하지 않으니 단축키 아끼기)
#showtooltip
/cast [known:야생의 정수] 야생의 정수
/cast [known:자연의 경계] 자연의 경계
/cast [known:정신 자극,@player] 정신 자극