1. 한 대상에게 두번 눌러도 채팅은 한번만 나가는 원거리공격+해골징+파티챗(점사요청) 매크로

 

#showtooltip

/대상 [@mouseover,harm,nodead]

/매크로중지 [noharm][dead]

/공격시작

/시전 [worn:활]활 발사;[worn:총]총 발사;[worn:석궁]석궁 발사;투척

/실행 if GetRaidTargetIndex("target")~=8 then SendChatMessage(">>{해골}%t<< 우선 점사","PARTY",nil,n)end

/실행 SetRaidTarget("target",8)

 

마우스오버한 대상이 있으면 그걸 대상으로 삼음

대상이 가까이 있으면 원거리공격은 안나가지만 해골징과 파티챗은 정상적으로 작동함

 

 

 

 

2. 마우스오버해두고 쓰면 대상 안 바뀌는 별징+파티챗(양변요청) 매크로

 

#showtooltip

/매크로중지[@mouseover,noharm][@mouseover,dead]

/p 법사님 >별< 양변ㄱㄱ

/실행SetRaidTarget("mouseover",1)

 

전투중 애드시 징찍으려고 타겟바꿔서 자동공격 끊기는 상황 방지

마우스오버한 대상에게 별징 찍고 현재 대상 유지하기 때문에 자동공격 유지

 

법사가 양변 안했을시 재촉하기위해 조건 안달았는데 혹시 원한다면 /p 줄을

/실행 if GetRaidTargetIndex("target")~=1then SendChatMessage("법사님 >별< 양변 ㄱㄱ","PARTY",nil,n)end

로 바꿔서 위와 비슷하게 대상에게 처음 징찍을때만 채팅 나가게 만들수 있음

 

비슷하게 /p 부분과 /실행줄 숫자만 바꿔서 다른 징박기, 다른 메즈 요청도 가능

 

 

 

 

3. 연타 시 가능한 대상에게 제압 / 연타 시 가능한 대상에게 복수 매크로

 

#showtooltip 제압

/시전 [form:1];전투 태세

/적선택

/매크로중지 [noharm][dead]

/공격시작

/시전 제압

 

#showtooltip 복수

/시전 [form:2];방어 태세

/적선택

/매크로중지 [noharm][dead]

/공격시작

/시전 복수

 

/적선택이 탭키랑 동일함 즉, 탭 제압이나 탭 복수를 각각 한키로줄인 것

적이 피하거나 내가 방어행동 취한걸 봤을때 적 수만큼 누른다면 시전 가능한 대상에게 스킬 쓸거임

추가로 어느 태세에서 쓰던지 제압,복수에 맞는 태세로 바꿔주고 그건 연타수에 포함되지 않음

 

 

 

4. 돌진 매크로

 

4-1, 돌진(1). 비전투 돌진, 전투 봉쇄 매크로

 

#showtooltip [combat]봉쇄;돌진

/시전 [combat,form:1/2]광폭 태세;[combat][form:1];전투 태세

/매크로중지 [noharm][dead]

/공격시작

/시전 [combat]봉쇄;돌진

 

비전투중에 돌진박고 전투중에 봉쇄박는 매크로

대상만 잡고 있다면 알아서 나감

어느 태세에서 쓰던지 맞는 태세로 바꿔주고 태세 바뀌는 동시에 스킬 나감(맞지않는 태세여도 한번 클릭으로 ok)

 

취향따라 /대상[@mouseover,harm,nodead]를 /매크로중지 줄 위에만 넣으면

마우스오버한 대상이 있으면 그걸 대상으로 삼고 스킬은 여전히 바로 나감

그 경우 툴팁도 #showtooltip[combat,@mouseover,harm,nodead][combat]봉쇄;[@mouseover,harm,nodead][]돌진으로 바꿔야 거리정보도 잘 나옴

 

 

 

4-2, 돌진(2). 전태, 비전투 돌진, 전투 천벼 매크로

 

#showtooltip

/시전 [noform:1]전투 태세;[combat]천둥벼락

/매크로중지 [noharm][dead]

/공격시작

/시전 [combat];[form:1]돌진

 

기본적으로 전태로 바꾸는 매크로, 추가로 누를 시 비전투 돌진, 전투 천벼

위의 매크로들과 달리 방태나 광태에서 한번 눌러도 바로 돌진이나 천벼가 나가는게 아니라

한번 누를시 전태로 바꾸는 키고 거기에 전태일시 누르면 추가로 부가기능을 단 매크로


마찬가지로 취향따라 /대상[@mouseover,harm,nodead]를 /매크로중지 전에 넣으셈

 

 

취향따라 돌진(1)과 돌진(2)중에서 고르면 될듯

돌진(2) 고르면 봉쇄도 따로 만들어야하는데 필요하면 댓글로 ㄱㄱ

 

 

 

 

5. 30분 쿨기 매크로

 

5-1, 쿨기(1). 태세따라 맞는 30분쿨기 쓰는 매크로

 

#showtooltip

/시전 [form:1]보복;[form:2]방패의벽;무모한 희생

 

나는 태세관리를 잘해서 이 매크로 하나만으로 30분쿨기 끝내겠다하면 쓰는 매크로

태세따라서 바뀌지않는 추가단축바에 놓고 쓰는 용도

실수로 방패의 벽 쓰려다 보복이나 무모한 희생 쓰게 되는경우 애도..

 

 

 

5-2, 쿨기(2). 어느 태세던지 원하는 쿨기 태세로 바꿔서 쓰는 매크로

 

#showtooltip 보복

/시전 [form:1];전투 태세

/시전 보복

 

#showtooltip 방패의 벽

/시전 [form:2];방어 태세

/시전 방패의 벽

 

#showtooltip 무모한 희생

/시전 [form:3];광폭 태세

/시전 무모한 희생

 

태세관리 삐끗할위험 안고갈 바에 원하는 스킬 확실히 쓰겠다 하면 쓰는 매크로

마찬가지로 태세따라서 바뀌지않는 추가단축바에 놓고 쓰는 용도

하지만 단축바 3칸이 필요해서 이렇게 쓰면 30분 쿨이라 별로 쓰지도 않는거에 단축바 낭비하는 느낌이 듬

그래도 현재 태세 확인 안해도 원하는 스킬 확실히 쓸수 있는 장점은 있음

 

 

취향따라 쿨기(1)과 쿨기(2)중 취사선택하면 될듯

기본단축바에 놓으면 쿨기(1) 매크로가 내장돼있는 셈인데

이게 30분 쿨을 기본단축바에 놓기엔 낭비하는 느낌이 들기도하고 하니 알아서 하셈

 

 

 

 

6. 방패필요 스킬들 매크로 팁) /클릭 매크로, 장비스왑 매크로 - 취향많이탐

 

사전준비.

 

/장착 한손장비이름

/장착 방패이름

 

이런 매크로 만들어서 추가행동 단축바위에 올려두기

(추천. 첫번째 우측 행동단축바나 두번째 우측 행동단축바에 올려두기)

밑으로는 우측행동단축바 2개중 왼쪽 맨밑에 놨다고 가정 : MultiBarLeftButton12

자기가 놓고싶은곳을 알려주면 맞는 번호 알려드림

 

방패 필요한 스킬들: 방패 막기, 방패 가격

이 스킬들에 원래 쓰던 매크로가 있다면, 그위에

 

/클릭 [worn:방패];MultiBarLeftButton12

/매크로중지 [noworn:방패]

 

추가하면 처음 클릭시 방패스왑. 두번째 클릭시 원래 스킬대로작동함

전투중엔 무기 스왑에 글쿨도니까 방가 차단할거면 1.5초고려해서 미리 스왑해두는게 좋음

 

예를 들어 방패 가격을 쓰려 한다면

 

#showtooltip 방패 가격

/클릭 [worn:방패];MultiBarLeftButton12

/매크로중지 [noworn:방패]

/시전 [form:3]전투 태세

/매크로중지 [noharm][dead]

/공격시작

/시전 방패 가격

 

이 정도로 쓸 수 있겠음

취향따라 /대상 마우스오버~~추가하고

또 취향따라 /ㄷ<%t> 방패 가격 추가해서 차단하는 전사다 티내보셈

 

장비스왑만 말고도 클릭매크로 더 응용해볼수도 있음

 

굳이 장비스왑할때 /클릭 넣은 이유는 무기 더 좋은거 나왔을때 

방패 필요한 스킬 2개 매크로에서 각각 바꾸지 않고

하나만 바꿔도 두개에서 효과 볼수 있기 때문에 이렇게 함

 

 

 

 

7. 차단 스킬 매크로

 

7-1. 태세에 따른 장비스왑후 차단 매크로

 

장비스왑은 위의 클릭 매크로를 위한 사전 작업을 해뒀다는 가정하에 씀

 

#showtooltip

/클릭 [worn:방패][form:3];MultiBarLeftButton12

/매크로중지 [noharm][dead][noworn:방패,noform:3]

/공격시작

/시전 [form:3]자루 공격;방패가격

 

취향따라 /대상 마우스~~

취향따라 /ㄷ<%t> 차단

 

장점은 검방이면 태세따라서 차단 두개

단점은 검방아닌데 전태방태에선 장비스왑이 들어가서 반응속도가 글쿨만큼 느릴수 있음

검방 특화 매크로

 

 

 

7-2. 장비에 따른 태세전환후 차단 매크로

 

#showtooltip [worm:방패]방패 가격;자루 공격

/시전 [worn:방패,form:3]전투태세;[worn:방패][form:3];광폭 태세

/매크로중지 [noharm][dead]

/공격시작

/시전 [worm:방패]방패가격;자루 공격

 

취향따라 /대상~~, /ㄷ ~~ 차단

 

장점은 무기 상관없이 바로 차단 가능

단점은 방패 꼈으면 자루공격 사용할 방법이 없음

쌍수나 양손 자주 쓸거 같다 하면 쓰는 매크로

 

 

취향이고 솔직히 2개다 따로 단축키 배정해서 쓰는게 낫다고 생각함. 굳이 합쳐야한다면 이렇게 쓰셈

 

 

 

 

잡담.

드루하다가 전사하니까 또다른 재미가 있네여

부캐로 키우고 있는 중이라 렙이 낮아 광태 관련 매크로는 안되는 게 있을 수도 있슴다

이론상은 될텐데 안되면 말해주세여

 

 

 

 

마지막으로 내가 쓰고있거나 쓸 매크로는 아니지만

 

8. 전사 탱킹 원키 매크로

 

#showtooltip

/시전 [combat];[form:1]돌진;전투 태세

/연속시전 reset=nocombat [combat,form:1]천둥벼락,방어 태세

/시전 [combat,form:1]사기의 외침

/매크로중지 [nocombat][noform:2]

/적선택

/공격시작

/시전 방어구 가르기

 

비전투 전태 아닐시 > 전태로 바꿈

 

비전투 전태일시 > 대상에게 돌진

 

전투 전태일시 분노20이상이고 처음클릭> 천벼

(분노 20미만이면 아무일도 일어나지 않음 = 클릭을 안한 셈 침)

 

전투 전태일시 분노10이상이고 두번째클릭> 방태로 바꾸고 사외(방태 어글 추가 적용) <<<무기특 전술숙련 2포 이상

(분노 10미만이거나 전술숙련2포 미만이면 방태로 바뀌기만 함, 사외 쓸 분노 없어서)

(그 경우 이미 방태로 바꼈으니 이 매크로로는 그 전투에서 더이상 사외 못 씀. 나머지 2개의 분노 조건에 비해 되돌릴 수 없으니 약간 더 유심히 봐주셈)

 

전투 방태일시 분노15이상이고 클릭할때마다 > 탭방가

(분노 15미만이면 탭만 함, 잘못 클릭했다면 몹 수만큼 빨리 눌러주면 다시 원래 몹으로 돌아올 수 있음)

 

분노 조건만 제대로 맞추면

전태 돌진 천벼 방태 사외 탭방가 탭방가 탭방가 ... 를 한키로 할 수 있음

11111111111로 탱킹 때우기 가능

예전에 전게에 원하시던분 있던거 같은데

연구해왔음 ㅇㅅㅇ

 

아직 151자라서

취향따라 /대상[combat];[form:1,@mouseover,harm,nodead] 같은거 맨 첫줄에 넣어서

돌진대상만 마우스오버로 지정하는것도 가능

 

 

개인적으론 말했듯이 안쓸거고 비추인데

원하면 쓰세여





모두 즐겁게 전사하십셔